Add 'nginxbeautifier/' from commit 'e2ca5007c4ff90e7962f657e1673fb451c73a66f'

git-subtree-dir: nginxbeautifier
git-subtree-mainline: e526d854eb
git-subtree-split: e2ca5007c4

nginxbeautifier/.SRCINFO

@@ -0,0 +1,15 @@
+pkgbase = nginxbeautifier
+	pkgdesc = nginx config file formatter and beautifier
+	pkgver = 1.0.19
+	pkgrel = 2
+	url = https://github.com/vasilevich/nginxbeautifier
+	arch = any
+	license = Apache
+	makedepends = git
+	makedepends = npm
+	depends = nodejs
+	source = nginxbeautifier::git+https://github.com/vasilevich/nginxbeautifier.git#commit=734ff631f254d8f17661d81e43927ba68e69f545
+	sha512sums = SKIP
+
+pkgname = nginxbeautifier
+

nginxbeautifier/PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: Sefa Eyeoglu <contact@scrumplex.net>
+# Contributor: Yosef Langer (vasilevich1234 dot gmail dot ...)
+
+_commit=734ff631f254d8f17661d81e43927ba68e69f545
+pkgname=nginxbeautifier
+pkgver=1.0.19
+pkgrel=2
+pkgdesc="nginx config file formatter and beautifier"
+arch=(any)
+url="https://github.com/vasilevich/nginxbeautifier"
+license=("Apache")
+depends=("nodejs")
+makedepends=("git" "npm")
+source=("$pkgname::git+https://github.com/vasilevich/nginxbeautifier.git#commit=${_commit}")
+sha512sums=('SKIP')
+
+
+prepare() {
+    cd "${pkgname}"
+
+    # remove junk
+    rm -rf ".idea/"
+}
+
+build() {
+    cd "${pkgname}"
+
+    # We create a taball of the project as "npm installing" (see package()) the directory itself only creates symlinks
+    npm pack
+}
+
+package() {
+    cd "${pkgname}"
+
+    npm install -g --prefix "${pkgdir}/usr" "${pkgname}-${pkgver}.tgz"
+    # Non-deterministic race in npm gives 777 permissions to random directories.
+    # See https://github.com/npm/npm/issues/9359 for details.
+    find "${pkgdir}/usr" -type d -exec chmod 755 {} +
+
+    # npm gives ownership of ALL FILES to build user
+    # https://bugs.archlinux.org/task/63396
+    chown -R root:root "${pkgdir}"
+
+    install -d "${pkgdir}/usr/share/doc/${pkgname}"
+    ln -s "/usr/lib/node_modules/${pkgname}/README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+}
+