# Maintainer: Giovanni Harting <539@idlegandalf.com>
# Contributor: Barry Smith <brrtsm at gmmal dot com>
# Contributor: jrdemasi <jrdemasi@gmai.com>
# Contributor: Fernando Manfredi <contact at acidhub.click> Contributor: Evan Teitelman <teitelmanevan at gmail dot com>
# Contributor: Ari Mizrahi <codemunchies@gmail.com>
# Contributor: CRT <cirkit@kode.email>

pkgname=ntopng
pkgver=4.2
_ndpiver=4.0
pkgrel=1
pkgdesc='A network traffic probe that shows the network usage'
arch=('x86_64' 'i686')
url='http://www.ntop.org/'
license=('GPL3')
depends=('redis' 'geoip' 'glib2' 'curl' 'libmaxminddb' 'libmariadbclient' 'libpcap' 'sqlite' 'json-c' 'zeromq')
makedepends=('automake' 'libtool' 'wget' 'libxml2')
source=("https://github.com/ntop/$pkgname/archive/$pkgver.tar.gz"
	"https://github.com/ntop/nDPI/archive/$_ndpiver.tar.gz"
	"$pkgname.service"
        "ntopng")
b2sums=('a9eaf7ea670dbd9c830696a4b017330e25a82307852a0a85d95ddbb4e32a3123d43eda1b686c359da1fef77e601cd3791dcdf257141e2e1d3ed7974b92edaac8'
        'ea0f333bd62622c1ab792137f9bbf2e35cb3790aae191c5caeaea36c7ce376bfa84633e99e321c16bcfbe5812d6674b825bdc4197297cee76064ed88f344a577'
        '74c0747a78bc5d2ae325103016523f48efa79c2e58121d9476d49cf204e1fc50c32247a0f96a10b2afaca55de0737a1f38bcfda205bf73804325e84a89763592'
        'f678b6eec141380ab6b95b7e8218145e3f2c2855ad55bbe5812e15befdbb48bc80826580db24b50417002b82bcb3115db213587d9cea9691cc6e6f7f5c919cb3')
validpgpkeys=('EFD9413B17293AFDFE6EA6F1402A088DEDF104CB')

build() {
  # build nDPI
  cd $srcdir/nDPI-$_ndpiver
  export CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2 -O2"
  ./autogen.sh
  ./configure
  make
  export NDPI_HOME=$srcdir/nDPI-$_ndpiver

  # build ntopng
  cd $srcdir/$pkgname-$pkgver
  ./autogen.sh
  ./configure --prefix=/usr --datadir=/usr/share
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver

  make install DESTDIR=$pkgdir

  mv $pkgdir/usr/{man,share/}
  install -Dm644 "$srcdir/$pkgname.service" "$pkgdir/usr/lib/systemd/system/$pkgname.service"
  install -Dm644 "$srcdir/$pkgname" "$pkgdir/etc/conf.d/$pkgname"
}