# Maintainer: Giovanni Harting <539@idlegandalf.com>
# Contributor: Iacopo Isimbaldi <isiachi@rhye.it>
# Contributor: Lubomir Krajcovic <lubomir.krajcovic(AT)gmail(DOT)com>
# Contributor: Vladimir Kutyavin <vlkut(AT)bk(DOT)ru>

pkgname=xtables-addons-dkms
pkgver=3.7
pkgrel=1
pkgdesc="Successor to patch-o-matic(-ng). Contains extensions that were not accepted in the main Xtables. DKMS flavor for kernels >= 3.7."
arch=('i686' 'x86_64')
license=('GPL2')
url="http://xtables-addons.sourceforge.net/"
depends=('dkms' 'iptables')
optdepends=('perl-text-csv-xs: required for building GeoIP database'
            'unzip: required for building GeoIP database')
makedepends=()
conflicts=(xtables-addons xtables-addons-git xtables-addons-multikernel)
replaces=(xtables-addons xtables-addons-git xtables-addons-multikernel)
source=(dkms.conf https://sourceforge.net/projects/${pkgname%-dkms}/files/Xtables-addons/${pkgname%-dkms}-${pkgver}.tar{.xz,.asc})
sha256sums=('c8989ec1ab0c3aaebf557fd19bc0391173a77fb5e7f8b3afc63d3f6593b3b5af'
            '045ee3fcfe5d6edb95483cf49e2446ff8cab4bb79411018b18354138b70c5eb5'
            'SKIP')
validpgpkeys=("2F8BFE96D14F8B560FBC1F1DA28BDFEEB5A2B2FF")

prepare() {
	# go to builddir
	cd "${srcdir}/xtables-addons-${pkgver}"

	# disable install-exec-hook (avoids useless calling of depmod -a at 'make install' stage)
	sed -i 's/^install-exec-hook:$/dont-run:/' Makefile.am
	# disable building of xt_ECHO (it's an example module, and it breaks the build)
	sed -i 's/^build_ECHO=.*$/build_ECHO=n/' mconfig
}

build() {
	cd "${srcdir}/xtables-addons-${pkgver}"

	./autogen.sh

	./configure \
		--prefix=/usr \
		--sysconfdir=/etc \
		--bindir=/usr/bin \
		--sbindir=/usr/bin \
		--libdir=/usr/lib \
		--mandir=/usr/share/man \
		--docdir=/usr/share/doc \
		--libexecdir=/usr/lib/iptables \
		--with-xtlibdir=/usr/lib/iptables \
		--without-kbuild

	make
}

package() {
	cp "${srcdir}/dkms.conf" "${srcdir}/xtables-addons-${pkgver}"
	sed -i -e "s/@VERSION@/${pkgver}/" "${srcdir}/xtables-addons-${pkgver}/dkms.conf"

	install -dm 755 "${pkgdir}"/usr/src
	cp -dr --no-preserve='ownership' "${srcdir}/xtables-addons-${pkgver}" "${pkgdir}/usr/src/xtables-addons-${pkgver}" 

	cd "${srcdir}/xtables-addons-${pkgver}"	
	make DESTDIR="${pkgdir}" install
}