added nginx-mainline-mod-vts

because AUR maintainer does not understand the advantages of a simple
rebuild

nginx-mainline-mod-vts/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Giovanni Harting <539@idlegandalf.com>
+# Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
+
+pkgname=nginx-mainline-mod-vts
+pkgver=0.1.18
+pkgrel=1
+
+_modname="nginx-module-vts"
+
+pkgdesc='Nginx virtual host traffic status module (module for mainline nginx)'
+arch=('x86_64')
+depends=("nginx-mainline")
+makedepends=('nginx-mainline-src')
+url="https://github.com/vozlt/nginx-module-vts"
+license=('BSD')
+
+source=($pkgname-$pkgver.tar.gz::https://github.com/vozlt/nginx-module-vts/archive/v$pkgver.tar.gz)
+
+b2sums=('700f48ec3ae7b38d4498b1ca6f7e08069befb4b76a20cc0619d16e613c1efb387eace906901fcb098159bc20acfc8723d98aec690e11deaff949f5612dd414f9')
+
+prepare() {
+	mkdir -p build
+	cd build
+	ln -sf /usr/src/nginx/auto
+	ln -sf /usr/src/nginx/src
+}
+
+build() {
+	cd build
+	/usr/src/nginx/configure --with-compat --add-dynamic-module=../$_modname-$pkgver
+	make modules
+}
+
+package() {
+	install -Dm644 "$srcdir"/$_modname-$pkgver/LICENSE \
+	               "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+	cd build/objs
+	for mod in ngx_*.so; do
+		install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
+	done
+}